TYPE
  ConstFlattened = flat(snum)
  State          = Var -> ConstFlattened
  lifted_bool    = flat(bool)

PROBLEM Constant_Propagation

  direction  : forward
  carrier    : State
  init       : bot
  init_start : [-> top]
  combine    : lub


TRANSFER

// in assignments calculate the new value of the variable and add it to the state
  ASSIGN(variable, expression) = 
      @\[variable -> evalAExp(expression, @)]

// in procedur calls pass the value of the actual argument to the formal parameter
  CALL(_, param, exp), call_edge = 
      @\[param -> evalAExp(exp, @)]

  CALL(_, _, _), local_edge = bot


// at the end of procedures reset the formal parameter
  END(_, param) =
      @\[param -> top]

IF(expression), true_edge = if (evalBExp(expression, @)=top) then bot
			else if !drop(evalBExp(expression, @)) then bot
			else @
			endif
			endif

IF(expression), false_edge = if (evalBExp(expression, @)=top) then bot
			else if drop(evalBExp(expression, @)) then bot
			else @
			endif
			endif

SUPPORT

  evalAExp :: Expression * State -> ConstFlattened
  evalAExp(expression, state) =
    case expType(expression) of
      "ARITH_BINARY" => case expOp(expression) of
        "+" => let valLeft  <= evalAExp(expSubLeft(expression),  state),
                   valRight <= evalAExp(expSubRight(expression), state) in
                 lift(valLeft + valRight);
        "-" => let valLeft  <= evalAExp(expSubLeft(expression),  state),
                   valRight <= evalAExp(expSubRight(expression), state) in
                 lift(valLeft - valRight);
        "*" => let valLeft  <= evalAExp(expSubLeft(expression),  state),
                   valRight <= evalAExp(expSubRight(expression), state) in
                 lift(valLeft * valRight);
        "/" => let valLeft  <= evalAExp(expSubLeft(expression),  state),
                   valRight <= evalAExp(expSubRight(expression), state) in
                 if valRight = 0 then
                   top
                 else lift(valLeft / valRight) endif;
        endcase;
      "ARITH_UNARY" =>
	case expOp(expression) of
          "-" => let value <= evalAExp(expSub(expression), state) in
                   lift(-(value));
        endcase;
      "VAR"   => state ( expVar(expression) );
      "CONST" => lift(expVal(expression));
      _       => error("Runtime Error: evalAExp applied to nonarithmetic Expression");
    endcase

evalBExp :: Expression * State -> lifted_bool
   evalBExp(expression, state) =
      case expType(expression) of
	"BOOL_BINARY" => case expOp(expression) of
				"<" => let valLeft <= evalAExp(expSubLeft(expression),  state),
                 			valRight <= evalAExp(expSubRight(expression), state) in
					lift(valLeft<valRight);
				"<=" => let valLeft <= evalAExp(expSubLeft(expression),  state),
                 			valRight <= evalAExp(expSubRight(expression), state) in
					lift(valLeft<=valRight);
				"=" => let valLeft <= evalAExp(expSubLeft(expression),  state),
                 			valRight <= evalAExp(expSubRight(expression), state) in
					lift(valLeft=valRight);
				">" => let valLeft <= evalAExp(expSubLeft(expression),  state),
                 			valRight <= evalAExp(expSubRight(expression), state) in
					lift(valLeft>valRight);
				">=" => let valLeft <= evalAExp(expSubLeft(expression),  state),
                 			valRight <= evalAExp(expSubRight(expression), state) in
					lift(valLeft>=valRight);
				"<>" => let valLeft <= evalAExp(expSubLeft(expression),  state),
                 			valRight <= evalAExp(expSubRight(expression), state) in
					lift(valLeft!=valRight);
			endcase;
	"BOOL_UNARY" => if (evalBExp(expSub(expression), state)=top) then top
			else lift(!drop(evalBExp(expSub(expression), state)))
			endif;
	"TRUE" => lift(true);
	"FALSE" => lift(false);
    endcase